Asignar parametro a dticker

[JoseAlvarez]

Saludos amigos.

en un cuadro de dialogo tengo esta linea de codigo:

Code: Select all | Expand

Redefine dtpicker oCalendario var dCalendario   id 4002  of oDlg_Reservas picture 'DD-MM-YYYY'

en ese mismo dialogo, hago la llamada a otro dialogo que tambien tiene un dtpicker

Code: Select all | Expand

Redefine dtpicker oCalendario2 var dCalendario2   id 4002  of oDlg_Reservas2 picture 'DD-MM-YYYY'

el caso es que necesito que en el segundo cuadro, el que llamo usando un boton, el detpicker muestre la misma fecha que el usuario haya seleccionado en el primero. He intentado pasando la variable como parametro y tambien con setdate y getdate, pero nada. no funciona.

Code: Select all | Expand

Function Calendar2(dCalendario) ... dCalendario2:=dCalendario...

Code: Select all | Expand

oCalendario2:SetDate(dCalendario)... oCalendario2:refresh() 

Siempre muestra la fecha del dia.

como hacerlo?

[karinha]

Etimado, intente con VARPUT()

Regards, saludos.

[JoseAlvarez]

Etimado, intente con VARPUT()

Regards, saludos.

Saludos master joao.

tambien lo intenté así. No funciona.

[karinha]

Estimado, ¿podrías darme un pequeño ejemplo? Subelo a Megaupload para que podamos descargarlo y probarlo, ¿de acuerdo?

Gracias, tks.

Regards, saludos.

[JoseAlvarez]

Amigo Joao.

Te dejo el Video para que lo veas mejor. Necesito que la fecha que se muestra en el primer dialogo, pase como parámetro y la tome el dtpicker del segundo dialogo.

https://goo.su/XFYo

[karinha]

Estimado: Fivewin ES FÁCIL, lo difícil es no enamorarse de él. jajajajaja.

Code: Select all | Expand

// C:\FWH\SAMPLES\DTPICKER.PRG -> Para: Jose Alvarez.

#Include "Fivewin.ch"
#Include "Dtpicker.ch"

MEMVAR Mensa, dFecha2, dFecha1, Eje_Pro

FUNCTION Main()

   LOCAL oDlg, oSay1, oFecha1, oFon1, oFon2, oFon3, otitu1, oFecha2, oBtn1,    ;
         oBtn2

   SET CENTURY ON
   SET DATE BRITISH
   SET EPOCH TO YEAR( DATE() ) - 30
       
   dFecha1 := Date()
   dFecha2 := Date()

   DEFINE FONT oFon1 NAME "TAHOMA" SIZE 0, -14 BOLD
   DEFINE FONT oFon2 NAME 'TAHOMA' SIZE 0, -12 BOLD
   DEFINE FONT oFon3 NAME 'TAHOMA' SIZE 0,  24 BOLD

   DEFINE DIALOG oDlg SIZE 460, 250 PIXEL TRUEPIXEL FONT oFon1                 ;
      STYLE nOr( WS_POPUP, WS_VISIBLE, WS_DLGFRAME )

   @ 10, 70 SAY otitu1 PROMPT " PERIODO DE INFORME " PIXEL OF oDlg             ;
      COLORS RGB( 0, 100, 0 ) FONT oFon3 UPDATE

   @ 060, 020 SAY "Ingrese Fecha Inicial" SIZE 160, 20 PIXEL OF oDlg RIGHT     ;
      FONT oFon1 UPDATE

   @ 060, 200 DTPICKER oFecha1 VAR dFecha1 OF oDlg SIZE 120, 30 PIXEL          ;
      PICTURE "@D" UPDATE

   oFecha1:bChange = { || If( oFecha1:lClosed .AND. oFecha1:lFocused, oFecha1:PostMsg( WM_KEYDOWN, VK_RIGHT ), ) }

   @ 125, 020 SAY "Ingrese Fecha Final" SIZE 160, 20 PIXEL OF oDlg RIGHT       ;
      FONT oFon1 UPDATE

   @ 125, 200 DTPICKER oFecha2 VAR dFecha2 OF oDlg SIZE 120, 30 PIXEL          ;
      PICTURE "@D" UPDATE

   oFecha2:bChange = { || If( oFecha2:lClosed .AND. oFecha2:lFocused, oFecha2:PostMsg( WM_KEYDOWN, VK_RIGHT ), ) }

   @ 180, 150 BTNBMP oBtn1 SIZE 70, 50 PROMPT "&Procesa" OF oDlg PIXEL 2007    ;
      FILENAME "..\bitmaps\16x16\floppy.bmp" FLAT                              ;
      FONT oFon2 TOOLTIP "PROCESA DATOS"                                       ;
      ACTION( Nuevo_periodo_Fechas( dFecha1, dFecha2 ) )

   @ 180, 300 BTNBMP oBtn2 SIZE 70, 50 PROMPT "&Salida" OF oDlg PIXEL 2007     ;
      FILENAME "..\bitmaps\16x16\Exit.bmp" FLAT                                ;
      FONT oFon2 TOOLTIP  "VOLVER"                                             ;
      ACTION( Eje_Pro := .F. , oDlg:End() )

   oBtn2:bClrGrad = { | lMouseOver | If( ! lMouseOver, ;
        { { 1.00,14481663,38075 },                     ;
          { 1.00,38075,14481663 } },                   ;
        { { 0.10,16777215,9363707 },                   ;
          { 0.10,9363707,16777215 } } ) }

   oBtn2:SetColor(0) // Oro

   ACTIVATE DIALOG oDlg CENTERED

   RELEASE FONT oFon1, oFon2, oFon3

RETURN NIL

FUNCTION Nuevo_periodo_Fechas( dFecha1, dFecha2 )

   LOCAL oDlg2, oSay1, oFecha1, oFon1, oFon2, oFon3, otitu1, oFecha2, oBtn1,   ;
         oBtn2, dFecha3, dFecha4, cTitle

   cTitle  := "CAMBIANDO FECHA DE JOSE ALVAREZ EN TIEMPO REAL"
   dFecha3 := dFecha1
   dFecha4 := dFecha2

   DEFINE FONT oFon1 NAME "TAHOMA" SIZE 0, -14 BOLD
   DEFINE FONT oFon2 NAME 'TAHOMA' SIZE 0, -12 BOLD
   DEFINE FONT oFon3 NAME 'TAHOMA' SIZE 0,  24 BOLD

   DEFINE DIALOG oDlg2 SIZE 460, 250 PIXEL TRUEPIXEL FONT oFon1 TITLE cTitle

   oDlg2:lHelpIcon := .F.

   @ 10, 70 SAY otitu1 PROMPT " PERIODO DE INFORME " PIXEL OF oDlg2            ;
      COLORS RGB( 0, 100, 0 ) FONT oFon3 UPDATE

   @ 060, 020 SAY "Ingrese Fecha Inicial" SIZE 160, 20 PIXEL OF oDlg2 RIGHT    ;
      FONT oFon1 COLOR METRO_ORANGE UPDATE

   @ 060, 200 DTPICKER oFecha1 VAR dFecha3 OF oDlg2 SIZE 120, 30 PIXEL         ;
      PICTURE "@D" UPDATE

   @ 125, 020 SAY "Ingrese Fecha Final" SIZE 160, 20 PIXEL OF oDlg2 RIGHT      ;
      FONT oFon1 COLOR METRO_ORANGE UPDATE

   @ 125, 200 DTPICKER oFecha2 VAR dFecha4 OF oDlg2 SIZE 120, 30 PIXEL         ;
      PICTURE "@D" UPDATE

   @ 200, 270 SAY otitu1 PROMPT "[email protected]" PIXEL OF oDlg2          ;
      SIZE 160, 20 COLORS METRO_COBALT FONT oFon2 UPDATE

   @ 180, 180 BTNBMP oBtn2 SIZE 70, 50 PROMPT "&Salida" OF oDlg2 PIXEL 2007    ;
      FILENAME "..\bitmaps\16x16\Exit.bmp" FLAT                                ;
      FONT oFon2 TOOLTIP  "Salida"                                             ;
      ACTION( Eje_Pro := .F. , oDlg2:End() )

   oBtn2:bClrGrad = { | lMouseOver | If( ! lMouseOver, ;
        { { 1.00,14481663,38075 },                     ;
          { 1.00,38075,14481663 } },                   ;
        { { 0.10,16777215,9363707 },                   ;
          { 0.10,9363707,16777215 } } ) }

   oBtn2:SetColor(0) // Oro

   ACTIVATE DIALOG oDlg2

   RELEASE FONT oFon1, oFon2, oFon3

RETURN NIL

// FIN / END - [email protected]

Regards, saludos.

[karinha]

https://imgur.com/SbQVRG5



Regards, saludos.