FiveTech Software tech support forums

Code: Select all | Expand

#include "FiveWin.ch"
function Main()
    LOCAL oGmail,hStore
    ? "Start..."
    hStore := readStore( hb_dirBase() + "gmail.json" )
    oGmail := TGmail():new()
    // USE Your ID and Secret Key. check README.md
    oGmail:setConfig( {;
        "client_id" => "xxxxxxxxxxxxxxxxx",;
        "client_secret" => "xxxxxxxxxxxxxxz",;
        "redirect_uri" => "http://localhost:2025/";
    } )
    if !empty( hStore[ "token" ] )
        oGmail:setToken( hStore[ "token" ] )
    endif
    ? "Connect..."
    onConnect( oGmail,hStore )
    ? "Send..."
    onSendMail( oGmail )
    ? "Disconnect..."
    onDisconnect( oGmail )
    saveStore( hb_dirBase() + "gmail.json", hStore )
RETURN( .T. )

function onConnect( oGmail,hStore )
    local cToken
    if !oGmail:isAuth()
        cToken := oGmail:auth()
        if !empty( cToken )
            hStore[ "token" ] := cToken
        else
            msgStop( "Authentication failed!" )
        endif
    endif
return nil

function onDisconnect( oGMail )
    local cProfile := hb_dirBase() + "profile_gmail.jpg"

    oGmail:revoke()
    if file( cProfile )
        ferase( cProfile )
    endif
return nil

function onSendMail( oGmail )
    if oGmail:send( "[email protected]", "Teste", "<b>Message from Gmail oAuth2</b>", .t., {} )
        msgInfo( "Mail sent!" )
    else
        msgStop( "Failed to send email. You may not have authorized the required permissions..." )
    endif
return nil

function readStore( cFile )
    local hStore
    if file( cFile )
        hb_jsonDecode( memoRead( cFile ), @hStore )
    endif
    if !hb_isHash( hStore )
        hStore := {;
            "token" => "";
        }
    endif
return hStore

function saveStore( cFile, hStore )
    hb_memoWrit( cFile, hb_jsonEncode( hStore ) )
return file( cFile )