XBrowse: report header and footer

[Enrico Maria Giordano]

Dear friends, I need to make a report from an XBrowse (oBrw:Report()) with an header in the first page and a footer in the last page. Is it possible?

EMG

[Enrico Maria Giordano]

Solved for footer:

oRpt:bPostEnd = { || oRpt:Say( ... ) }

Any ideas for header? I'm trying with oRpt:bInit but it prints after the columns header.

EMG

[FranciscoA]

Enrico.
Try this, please:

Code: Select all

   ACTIVATE REPORT oReport ;
      ON ENDPAGE ( oReport:oHeader := TrLine():New({}) , oReport:oTitle := TrLine():New({}) , oReport:nTitleRow := 0 )
 

[Enrico Maria Giordano]

Thank you. Unfortunately, the page number is overwritten by the double line from the second page on. I tried to reduce the height of the list without results.

EMG

[FranciscoA]

Thank you. Unfortunately, the page number is overwritten by the double line from the second page on. I tried to reduce the height of the list without results.

EMG

Enrico, can you test?

Code: Select all

//------------------------------------------//
Function TituSoloEnPag1()
local oReport, oFont

   DBUSEAREA(.T.,,"CUSTOMER","CUST",.T.)
   DBGOTOP()

   DEFINE FONT oFont NAME "ARIAL" SIZE 0,-10

   REPORT oReport ;
      TITLE "PROBANDO TITULO-HEADER SOLO EN PRIMERA PAGINA",;
            "UTILIZAMOS 'CUSTOMER.DBF'",;
            "LISTADO DE NUESTROS CLIENTES" ;
      FONT oFont;
      HEADER Dtoc(Date()), "Pag: " + str(oReport:nPage,3) RIGHT ;
      PREVIEW

      COLUMN TITLE "FIRST"  DATA Field->FIRST  SIZE 20
      COLUMN TITLE "LAST"   DATA Field->LAST   SIZE 20
      COLUMN TITLE "STREET" DATA Field->STREET SIZE 30
      COLUMN TITLE "CITY"   DATA Field->CITY   SIZE 20
      COLUMN TITLE "STATE"  DATA Field->STATE  SIZE 10
   ENDREPORT

   ACTIVATE REPORT oReport ;
      ON ENDPAGE ( oReport:oTitle := TrLine():New({}) )

      //Header y Title solo en la primer pagina.
      //ON ENDPAGE ( oReport:oHeader := TrLine():New({}) , oReport:oTitle := TrLine():New({}) , oReport:nTitleRow := 0 )

      //Header y Title en pag 1, y en siguientes header y espacio vacio del title.
      //ON ENDPAGE ( oReport:oTitle := TrLine():New({}) )

      CUST->(DBCLOSEAREA())
      RELEASE oFont

Return nil


 

[Enrico Maria Giordano]

Thank you, Francisco. In your sample, the header is printed on the first page, ok, but the header space is left blank from the second page on.

EMG

[FranciscoA]

Thank you, Francisco. In your sample, the header is printed on the first page, ok, but the header space is left blank from the second page on.

EMG

Enrico, here.

Code: Select all

//------------------------------------------//
Function TituSoloEnPag1()
local oReport, oFont

   DBUSEAREA(.T.,,"CUSTOMER","CUST",.T.)
   DBGOTOP()

   DEFINE FONT oFont NAME "ARIAL" SIZE 0,-10

   REPORT oReport ;
      TITLE "PROBANDO TITULO-HEADER SOLO EN PRIMERA PAGINA",;
            "UTILIZAMOS 'CUSTOMER.DBF'",;
            "LISTADO DE NUESTROS CLIENTES" ;
      FONT oFont;
      HEADER Dtoc(Date()), "Pag: " + str(oReport:nPage,3) RIGHT ;
      PREVIEW

      COLUMN TITLE "FIRST"  DATA Field->FIRST  SIZE 20
      COLUMN TITLE "LAST"   DATA Field->LAST   SIZE 20
      COLUMN TITLE "STREET" DATA Field->STREET SIZE 30
      COLUMN TITLE "CITY"   DATA Field->CITY   SIZE 20
      COLUMN TITLE "STATE"  DATA Field->STATE  SIZE 10
   ENDREPORT

   ACTIVATE REPORT oReport ;
         ON ENDPAGE ( oReport:oTitle := TrLine():New({}), oReport:nTitleRow := oReport:oHeader:nHeight + oReport:nTopMargin )

      CUST->(DBCLOSEAREA())
      RELEASE oFont

Return nil
 

Regards.

[Enrico Maria Giordano]

Great! Many thanks, Francisco!

EMG

[FranciscoA]

Nice to collaborate.

[nageswaragunupudi]

Thank you. Unfortunately, the page number is overwritten by the double line from the second page on. I tried to reduce the height of the list without results.

This is a bug. Happens when oRep:lJoin or oRep:lSeparator is true.
We will fix it soon and inform you.

[Enrico Maria Giordano]

Thank you, Master Rao!

EMG