FiveTech Software tech support forums

www.FiveTechSoft.com
https://fivetechsoft.com/forums/

Reproducir archivo WMV

https://fivetechsoft.com/forums/viewtopic.php?f=6&t=24840

Page 1 of 1

Reproducir archivo WMV

Posted: Sat Sep 15, 2012 5:44 pm
by Orbex
Hola Amigos del Foro

Desearia saber en que forma puedo ejecutar un archivo de tipo WMV Ej. TUTOR.WMV desde mi programa. No he logrado llamar al WMPLAYER.EXE que supongo ha de ser el programa de Windows que reproduce esos formatos.

Alguna ayuda por favor...

Se trata de que con un boton desde el programa se pueda ejecutar un video tutorial que esta en formato WMV

Gracias por su ayuda..

Saludos

Re: Reproducir archivo WMV

Posted: Sat Sep 15, 2012 6:25 pm
by jll-fwh
Hola Orbex:

Te paso mi metodo de la clase que me cree para este fin:

Code: Select all

/*------------------------------------------------------------------------------*/
METHOD LoadActive() CLASS TMediaX
/*------------------------------------------------------------------------------*/
/* WMPlayer.OCX.7                                                               */
/* Mas informacion de las propiedades en:                                       */
/* http://msdn.microsoft.com/en-us/library/ms930698.aspx                        */
/*------------------------------------------------------------------------------*/
/* oActiveX:GetProp( "ShowControls" ) => Controla si muestra la barra botones   */
/* oActiveX:GetProp( "AutoSize" )     => Si se ajusta al tamaño del cotrol      */
/*------------------------------------------------------------------------------*/

   ::oActiveX := TActiveX():New( ::oDlg, "MediaPlayer.MediaPlayer.1",;
                                 ::oDlg:nTop                        ,;
                                 ::oDlg:nLeft                       ,;
                                 ::oDlg:nRight                      ,;
                                 ::oDlg:nBottom-5                    )

   ::oActiveX:SetProp( "FileName", ::cFile )

Return NIL
 
NOTA: a Tener en cuenta que dependiente del S.O se pueden reproducir determinados ficheros.

Un saludo
JLL

Re: Reproducir archivo WMV

Posted: Sat Sep 15, 2012 7:16 pm
by Sistem

Code: Select all

MostraWmp()
*-----------------------------------------------------------------------------
Function MostraWmp()
 Local oDlg, oActiveX, cRadioTv:="http://www.tempofm.com.br/tempofm3.asx"

 DEFINE DIALOG oDlg TITLE "Radio/Tv"  FROM 1,1 TO 360,430 PIXEL

 oDlg:lHelpIcon := .F.

 oDlg:nStyle := nOr( WS_MINIMIZEBOX ,WS_VISIBLE, WS_CAPTION, WS_SYSMENU ) //, WS_THICKFRAME

 ACTIVATE DIALOG oDlg CENTERED ; //NOMODAL;   
 ON INIT ( oActiveX := ActivaWMP( oDlg, oActiveX, cRadioTv ), ToolBar(oDlg, oActiveX), MenuRadioTv(oDlg, oActiveX) );
 VALID ( oActiveX :DO( "Stop" ), oActiveX :End(), .T. )

Return nil
*-----------------------------------------------------------------------------
Function ActivaWMP( oDlg, oActiveX, cRadioTv )

 oActiveX = TActiveX():New( oDlg, "MediaPlayer.MediaPlayer.1",;
 oDlg:nTop+30, oDlg:nLeft, oDlg:nRight, oDlg:nBottom-50 )

 oActiveX :SetProp( "FileName", cRadioTv )

Return( oActiveX )
*-----------------------------------------------------------------------------
Function ToolBar(oDlg, oActiveX)
Local oToolBar, cTitle:="Radio Tempo FM"

  DEFINE ButtonBar oToolBar SIZE 50,28 OF oDlg TOP 2007

  @ 002, 002 COMBOBOX cTitle ITEMS {"Radio Tempo FM",;
                                    "Radio Jovempan (Campinas)",;
                                    "-------------------------",;
                                    "Tv Canção Nova",;
                                    "Tv Rai News (Italia)",;
                                    "-------------------------",;
                                    "Escolher Arquivo"} PIXEL OF oToolBar SIZE 250,150 ON CHANGE MudaRadioTV(cTitle, oDlg, oActiveX)

Return nil
*-----------------------------------------------------------------------------
Function MudaRadioTV(cTitle, oDlg, oActiveX)
Local cFile, cString

oActiveX :DO( "Stop" )
If cTitle = "Radio Tempo FM"
   oActiveX :SetProp( "FileName", "http://www.tempofm.com.br/tempofm3.asx", "Radio Tempo FM" )
ElseIf cTitle = "Radio Jovempan (Campinas)"
   oActiveX :SetProp( "FileName", "http://www.dnip.com.br/link/jovempancampinas.wmx" )
ElseIf cTitle = "Radio Canção Nova"
   oActiveX :SetProp( "FileName", "http://www.cancaonova.com/radiofm.asx" )
ElseIf cTitle = "Tv Canção Nova"
   oActiveX :SetProp( "FileName", "http://www.cancaonova.com/tvcn.asx" )
ElseIf cTitle = "Tv Rai News (Italia)"
   oActiveX :SetProp( "FileName", "http://mediapolis.rai.it/relinker/relinkerServlet.htm?cont=1" )
ElseIf cTitle = "Radio Verdes Mares"
   oActiveX :SetProp( "FileName", "http://187.110.226.22:8122" )
ElseIf cTitle = "Tv CM (Musica Argentina)"
   oActiveX :SetProp( "FileName", "mms://www.cmtv.com.ar:1234" )
ElseIf cTitle = "Radio FM93"
   oActiveX :SetProp( "FileName", "http://187.110.226.22:8036")
ElseIf cTitle = "Escolher Arquivo"
   cString := "wav|*.wav|mp4|*.mp4|*.*|*.*|"
   cFile := cGetFile( cString, "Selecione um arquivo",, CurDrive()+":\"+GetCurDir() )
   If "*"$cFile .or. !File(cFile)
      cFile:=""
   Else
      oActiveX :SetProp( "FileName", cFile )
   Endif
Endif

Return nil
*-----------------------------------------------------------------------------
Static Function MenuRadioTv(oDlg, oActiveX)
Local oMenu

  MENU oMenu 2007
     MENUITEM "&Rádios"
     MENU
        MENUITEM "&teste"
        MENU
          MENUITEM "Radio Verdes Mares"  action MudaRadioTV("Radio Verdes Mares", oDlg, oActiveX)
          MENUITEM "Radio FM93" action MudaRadioTV("Radio FM93", oDlg, oActiveX)
        ENDMENU
        MENUITEM "Radio Canção Nova" action MudaRadioTV("Radio Canção Nova", oDlg, oActiveX)
     ENDMENU
     MENUITEM "&Tvs"
     MENU
        MENUITEM "&Tv Brasil"
        MENU
          MENUITEM "Tv Canção Nova" action MudaRadioTV("Tv Canção Nova", oDlg, oActiveX)
        ENDMENU
        MENUITEM "&Tv Internacional"
        MENU
          MENUITEM "Tv Rai News (Italia)" action MudaRadioTV("Tv Rai News (Italia)", oDlg, oActiveX)
          MENUITEM "Tv CM (Musica Argentina)" action MudaRadioTV("Tv CM (Musica Argentina)", oDlg, oActiveX)
        ENDMENU
     ENDMENU
  ENDMENU

  oDlg:setmenu(oMenu)

RETURN oMenu
remove NOMODAL
ACTIVATE DIALOG oDlg CENTERED; //NOMODAL;

ex: download wmp.prg
http://www.xup.in/dl,82083752/wmp.prg/

Re: Reproducir archivo WMV

Posted: Sat Sep 15, 2012 10:06 pm
by Orbex
Gracias amigos por responder tan pronto


Perdonen mi ignorancia, pero como uso esos codigos ???

Gracias por la ayuda

Re: Reproducir archivo WMV

Posted: Sun Sep 16, 2012 4:05 pm
by Eoeo
AND ON WIN7 NOT RUN ----CRASH

Re: Reproducir archivo WMV

Posted: Mon Sep 17, 2012 7:42 pm
by acuellar
Amigos,

Como se hace para que cierre el dialogo y reproducir otro.

Gracias por la ayuda.

Saludos,

Adhemar
All times are UTC
Page 1 of 1

Powered by phpBB® Forum Software © phpBB Limited