PROBLEMAS CON XHARBOUR

[ROBER68]

Hola he migrado mis sistemas a xHarbour y en algunas computadoras me marca este error
Error description: Error BASE/1082 Argument error: -
Called from TWBROWSE:PAINT(1067)
Called from TWBROWSE:DISPLAY(2933)
Called from TWBROWSE:HANDLEEVENT(0)
Called from _FWH(3164)
Called from SYSREFRESH(0)

En la mayoria no lo marca pero en algunas si

[Antonio Linares]

Que versión de FWH estas usando ?

[ROBER68]

FWH707

[ROBER68]

FWH707

[Antonio Linares]

Roberto,

Por favor compara este código con el método Paint() contenido en tu wbrowse.prg (correspondiente a la versión 7.07 de FWH):

Code: Select all

METHOD Paint() CLASS TWBrowse
 
   local n := 1, nSkipped := 1, nLines
   local aInfo := ::DispBegin()
 
   FillRect( ::hDC, GetClientRect( ::hWnd ), ::oBrush:hBrush )
 
   if ::lIconView
      ::DrawIcons()
      ::DispEnd( aInfo )
      return 0
   endif
 
   if ::nRowPos == 1 .and. ! Empty( ::cAlias ) .and. ;
      Upper( ::cAlias ) != "ARRAY"
      if ! ( ::cAlias )->( EoF() )
         ( ::cAlias )->( DbSkip( -1 ) )
         if ! ( ::cAlias )->( BoF() )
            ( ::cAlias )->( DbSkip() )
         endif
      endif
   endif
 
   WBrwLine( ::hWnd, ::hDC, 0, ::aHeaders, ::GetColSizes(),;
               ::nColPos, ::nClrForeHead, ::nClrBackHead,;
               If( ::oFont != nil, ::oFont:hFont, 0 ),.f.,;
                  ::aJustify, nil, ::nLineStyle,,, ::oVScroll, ::bLogicLen )
 
   if ( ::nLen := Eval( ::bLogicLen, Self ) ) > 0
 
      ::Skip( 1 - ::nRowPos )
 
      #ifndef __CLIPPER__
         nLines = ::nRowCount()
         while n <= nLines .and. nSkipped == 1
            ::DrawLine( n )
            nSkipped = ::Skip( 1 )
            if nSkipped == 1
               n++
            endif
         end
         ::Skip( ::nRowPos - n )
      #else
          // WBrwPane() returns the n� of visible rows
          // WBrwPane recieves at aColSizes the Array or a Block
          // to get dinamically the Sizes !!!
         ::Skip( ::nRowPos - wBrwPane( ::hWnd, ::hDC, Self, ::bLine,;
              ::aColSizes, ::nColPos, ::nClrText, ::nClrPane,;
              If( ::oFont != nil, ::oFont:hFont, 0 ), ::aJustify, ::nLineStyle ) )
      #endif
 
      if ::nLen < ::nRowPos
         ::nRowPos = ::nLen
      endif
 
      ::DrawSelect()
   endif
 
   if ! Empty( ::cAlias ) .and. Upper( ::cAlias ) != "ARRAY"
      ::lHitTop    = ( ::cAlias )->( BoF() )
      ::lHitBottom = ( ::cAlias )->( EoF() )
   endif
 
   ::DispEnd( aInfo )
 
return 0
 
//----------------------------------------------------------------------------//