Page 1 of 4
Tcbrowse 2 colour one for each line
Posted: Thu Nov 15, 2007 3:43 pm
by AHF
Hi,
Is there any way to have a 2 colours one for each line in tcbrowse with / wihtou lcellstyle
Antonio
Posted: Thu Nov 15, 2007 10:52 pm
by Antonio Linares
Antonio,
Do you mean using FWH own Class TCBrowse ?
Posted: Thu Nov 15, 2007 11:11 pm
by AHF
Yes.
Antonio
Posted: Thu Nov 15, 2007 11:23 pm
by James Bott
AHF,
The below info is from my notes file. Note that you have indexes, filters, and deleted records to handle, so the solution has to consider these.
James
---------------------------------
8/24/2007 Update: Antonio posted this one.
oBrw:nClrPane := { || If( OrdKeyNo() % 2 == 0, RGB( 230, 230, 230), RGB( 190, 215, 190 ) ) }
----------------------
This is a much better one, but only for objects. Unfortunately dbskip() only returns nil so you can't do this without a database object. [Update: There is an undocumented function _dbskipper() that does return the number of records skipped, so perhaps this could be done without a database object.]
lClrFlag:=.f.
oLbx:bSkip:={| nRecs | (nRecs:= ::oInvmast:skipper( nRecs ), lClrFlag:=if(nRecs/2 = int(nRecs/2), lClrFlag,!lClrFlag), nRecs) }
oLbx:nClrPane := { || if(lClrFlag, rgb(255,255,235), rgb(192,208,179)) }
The above works with or without indexes, filters, and deleted records.
// end
Posted: Thu Nov 15, 2007 11:50 pm
by AHF
James,
Thanks.
Antonio
Posted: Fri Nov 16, 2007 8:35 am
by StefanHaupt
AHF,
here is another working solution
Code: Select all
...
::oBrw:bBkColor := {|nRow,nCol,nStyle| TcBrwCol (nRow,nStyle,::oBrw, aColorK) }
...
FUNCTION TcBrwCol ( nRow, nStyle, oBrw, aColor )
LOCAL nColor
DEFAULT aColor := {RGB( 102, 205, 170 ),RGB( 32, 178, 170 )}
//IF nStyle = 0
IF IsEven( nRow )
nColor := aColor[1]
ELSE
nColor := aColor[2]
ENDIF
//ENDIF
RETURN ( nColor )
FUNCTION IsEven( nVal )
RETURN IIF( nVal = Round( nVal/2, 0 )*2, .T., .F. )
Posted: Fri Nov 16, 2007 9:49 am
by AHF
Problem solved. Thanks for your help.
Antonio
Posted: Wed Jan 09, 2008 2:56 pm
by AHF
Hello,
I return to same problem because using OrdKeyNo in a network the application is crawling. Without it it works great!. However the users are claiming for a 2 colors lines.
How can I solve it ?
Any ideas ?
Antonio
Posted: Wed Jan 09, 2008 4:28 pm
by James Bott
AHF,
There are two solutions above that don't use OrdKeyNo(), have you tried them?
James
Posted: Wed Jan 09, 2008 4:35 pm
by AHF
James,
Yes.
The problem with those solutions is when you begin to skip over the last visible line of the browse (line by line) you always get the smae rownr and it stops working.
It only works when you repaint all the browse. (pg up or down)
Antonio
Posted: Wed Jan 09, 2008 4:37 pm
by James Bott
AHF,
>The problem with those solutions is when you begin to skip over the last visible line of the browse (line by line) you always get the smae rownr and it stops working.
It only works when you repaint all the browse. (pg up or down)
I have never had that problem. Can we see the code you are using?
James
Posted: Wed Jan 09, 2008 5:03 pm
by James Bott
AHF,
Below is a working example. Use it with the fw\samples\customer.dbf file.
Regards,
James
Code: Select all
// Purpose : Sample TCBrowse with alternating color rows
// Author : James Bott
// Date : 1/9/2008
#include "fivewin.ch"
#include "TCBrowse.ch" // <-- Important
function main()
local oWnd, oCustomer, oBrw, lClrFlag
use customer
database oCustomer
define window oWnd title "TCBrowse Test"
@ 0,0 browse oBrw of oWnd update
oBrw:setoDBF( oCustomer )
oBrw:cAlias := oCustomer:cAlias // required
add column to browse oBrw field first
add column to browse oBrw field last
lClrFlag:=.f.
oBrw:bSkip:={| nRecs | (nRecs:= oCustomer:skipper( nRecs ), lClrFlag:=if(nRecs/2 = int(nRecs/2), lClrFlag,!lClrFlag), nRecs) }
oBrw:nClrPane := { || if(lClrFlag, rgb(255,255,235), rgb(192,208,179)) }
oWnd:oClient:=oBrw
activate window oWnd
return nil
Posted: Wed Jan 09, 2008 5:44 pm
by AHF
James,
I don't work with database objects. I have my own skip blocks.
Antonio
Posted: Wed Jan 09, 2008 5:47 pm
by James Bott
AHF,
>I don't work with database objects. I have my own skip blocks.
Database objects are not required. Show me your skipblock.
James
Posted: Wed Jan 09, 2008 5:48 pm
by Antonio Linares
Antonio,
Stefan proposed you, in this thread, a solution that does not use the DBF at all.
Its based on the painted row number. Please review it, thanks