FiveTech Software tech support forums

Posted: **Wed Oct 14, 2009 11:01 pm**

I am having a problem with the ON CHANGE clause of the Radio class(es). It seems the ON CHANGE event is firing when the dialog or window containing the Radio button is updated, even when the value is unchanged. Is this by design or a bug?

Thanks.

Posted: **Thu Oct 15, 2009 12:08 am**

Activate Dialog etc.. On Init SetRadioChange()

Procedure SetRadioChange()
oRadio:bChange := {|| MyFunctionWhenChange() }

Return

[;)]

Posted: **Thu Oct 15, 2009 5:34 am**

Please try and review FWH\samples\TestRad.prg

That example uses the ON CHANGE clause and here it works fine

Posted: **Thu Oct 15, 2009 2:23 pm**

Antionio,

Here is a modified testrad.prg to demonstrate the problem. It's a silly example, but it demonstrates how many times the bChange block is exectued. See below for the problem id and fix:

Code: Select all

// Radio Buttons management sample

#include "FiveWin.ch"

//----------------------------------------------------------------------------//

function Main()

   local oDlg, oRadMenu
   local nOption := 2

   SET _3DLOOK ON

   DEFINE DIALOG oDlg RESOURCE "Radios"

   REDEFINE RADIO oRadMenu VAR nOption ID 110, 120, 130, 140, 150 OF oDlg ;
      ON CHANGE MsgInfo( "Hello" ) ;
      UPDATE

   REDEFINE BUTTON ID 100 OF oDlg ACTION oRadMenu:GoNext() ;
      WHEN nOption == 3

   REDEFINE BUTTON ID 102 OF oDlg ACTION oRadMenu:GoPrev()

   ACTIVATE DIALOG oDlg CENTERED ;
     ON INIT ( oDlg:Refresh(), oDlg:Update() )

   SET _3DLOOK OFF

return nil

//----------------------------------------------------------------------------//

The problem is here:

Code: Select all

METHOD nOption( nNewOption ) CLASS TRadMenu

   if nNewOption != nil
      Eval( ::bSetGet, nNewOption )
      if ::bChange != nil                         
         Eval( ::bChange, Self )        /* <--- This runs every time the container is updated or painted */
      endif
   else
      return Eval( ::bSetGet )
   endif

return nil

My fix is here:

Code: Select all

METHOD nOption( nNewOption ) CLASS TRadMenu

   if nNewOption != nil
      IF Eval( ::bSetGet ) != nNewOption                  /* <----- Added this to check if we even need an update, value may already be set!! */
        Eval( ::bSetGet, nNewOption )
        if ::bChange != nil
           Eval( ::bChange )                   
        endif
      ENDIF
   else
      return Eval( ::bSetGet )
   endif

return nil

Posted: **Thu Oct 15, 2009 3:48 pm**

What do you need this clause for ?

Code: Select all

...  ON INIT ( oDlg:Refresh(), oDlg:Update() )

try to remove it. Unless I am missing something, I think that you don't need it

Posted: **Thu Oct 15, 2009 4:16 pm**

Antonio,

As I said, it's a silly example, but it causes the event to fire repeatedly. In the real world, I have calculations tied to the ON CHANGE clause. The problem is, they run even if the value is already set and unchanged. The fix in my original post solves the problem.

My ultimate question, regardless of the silly example, is...why does the bChange block execute *at all* during dialog updates or refreshes *if* the value is unchanged. BTW, I was mistaken, the initial dialog painting does not cause the bChange eval.

Here is a more realistic example - click either the "Prev" or "Next" button to see the behavior:

Code: Select all

// Radio Buttons management sample

#include "FiveWin.ch"

//----------------------------------------------------------------------------//

function Main()

   local oDlg, oRadMenu
   local nOption := 2

   SET _3DLOOK ON

   DEFINE DIALOG oDlg RESOURCE "Radios"

   REDEFINE RADIO oRadMenu VAR nOption ID 110, 120, 130, 140, 150 OF oDlg ;
      ON CHANGE MsgInfo( "Hello" ) ;
      UPDATE

   REDEFINE BUTTON ID 100 OF oDlg ;
      ACTION oDlg:Update()

   REDEFINE BUTTON ID 102 OF oDlg ;
      ACTION oDlg:Update()

   ACTIVATE DIALOG oDlg CENTERED

   SET _3DLOOK OFF

return nil

//----------------------------------------------------------------------------//

Andy

Posted: **Thu Oct 15, 2009 4:31 pm**

Andy,

>why does the bChange block execute *at all* during dialog updates or refreshes *if* the value is unchanged.

This does seem like a valid point and it also seems you have found a good solution.

Antonio,

Do you see any problems with his proposed change?

James

Posted: **Thu Oct 15, 2009 8:20 pm**

Andy, James,

Got it

Already implemented as proposed for next FWH 9.10 build

Thanks!

FiveTech Software tech support forums

RADIO "ON CHANGE" FIRES WHEN DIALOG UPDATED (WAS PAINTED)

RADIO "ON CHANGE" FIRES WHEN DIALOG UPDATED (WAS PAINTED)

Re: RADIO BUTTON "ON CHANGE" FIRES WHEN DIALOG IS PAINTED

Re: RADIO BUTTON "ON CHANGE" FIRES WHEN DIALOG IS PAINTED

Re: RADIO BUTTON "ON CHANGE" FIRES WHEN DIALOG IS PAINTED

Re: RADIO BUTTON "ON CHANGE" FIRES WHEN DIALOG IS PAINTED

Re: RADIO BUTTON "ON CHANGE" FIRES WHEN DIALOG IS PAINTED

Re: RADIO BUTTON "ON CHANGE" FIRES WHEN DIALOG IS PAINTED

Re: RADIO "ON CHANGE" FIRES WHEN DIALOG UPDATED (WAS PAINTED)