FiveTech Software tech support forums

Code: Select all

//----------------------------------------------------------------------------//
//
// Function para descargar ficheros desde GDrive
// El truquillo está en la dirección de la descarga, el resto es trivial
//
// The ID of the file you get in the address offered by GMail when sharing the file.
// Just change the access address and add that ID
//
// https://docs.google.com/uc?export=download&id=
//----------------------------------------------------------------------------//

#include "Fivewin.ch"

//----------------------------------------------------------------------------//

Function Main()

   local cUrl

   // 
   cUrl   := "https://docs.google.com/uc?export=download&id=YOUR_ID_OF_FILE"
   Cn_DownLoad( cUrl, .F., "c:\fwh\mydown.zip" )
   //

Return nil

//----------------------------------------------------------------------------//

Function Cn_DownLoad( cUrl, lText, cFileTarget )

   local oHttp
   local cContents     := ""
   DEFAULT cUrl        := ""
   DEFAULT lText       := .F.
   DEFAULT cFileTarget := ""

   if !Empty( cUrl )
      DeleteUrlCacheEntry( cUrl )
      
      TRY
         oHttp     := FWGetOleObject( "MSXML2.ServerXMLHTTP.3.0" )
         //oHttp     := CreateObject( "MSXML2.ServerXMLHTTP.3.0" )
         oHttp:Open( "GET", cUrl, .F. )
         oHttp:Send()
         oHttp:WaitForResponse()
         DEFAULT lText := .F.
         if lText
            cContents  := oHttp:ResponseText()
         else
            cContents  := oHttp:ResponseBody()
         endif
      CATCH

      END
      
      if Len( cContents ) > 0 .and. !Empty( cFileTarget )
         MemoWrit( cFileTarget, cContents )
      else
         MsgInfo( "Error en la descarga", "Atencion" )
      endif
   else
      MsgInfo( "URL proporcionada en blanco", "Error en la descarga" )
   endif
Return nil

//----------------------------------------------------------------------------//
DLL STATIC FUNCTION DELETEURLCACHEENTRY( cUrl AS LPSTR ) AS BOOL;
    PASCAL FROM "DeleteUrlCacheEntryA" LIB "wininet.dll"
//----------------------------------------------------------------------------//